# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=1

inherit eutils toolchain-funcs

MY_P=${PN}-x11-src-${PV}
DESCRIPTION="Ultimate++ is a C++ cross-platform rapid application development framework"
HOMEPAGE="http://www.ultimatepp.org/"
SRC_URI="mirror://sourceforge.net/project/${PN}/${PN}/${PV}/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND="dev-libs/atk
	dev-libs/expat
	dev-libs/glib
	media-libs/freetype
	x11-libs/cairo
	x11-libs/gtk+:2
	x11-libs/libnotify
	x11-libs/libXinerama
	x11-libs/pango"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_compile () {
	local libs_used="x11 freetype2 gtk+-2.0 glib-2.0 cairo pango atk"
	emake -C uppsrc \
		LIBPATH="$($(tc-getPKG_CONFIG) --libs-only-L ${libs_used})" \
		CINC="-I. $($(tc-getPKG_CONFIG) --cflags ${libs_used})" \
		CXX="$(tc-getCXX)" \
		CC="$(tc-getCXX)" \
		AR="$(tc-getAR) -sr" \
		LD="$(tc-getLD)" \
		CFLAGS="${CFLAGS}" \
		CXXFLAGS="${CXXFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		|| die "make failed"
}

src_install () {
	newbin uppsrc/ide.out theide || die
	rm -rf uppsrc/_out || die
	insinto /usr/share/${PN}
	doins -r GCC.bm bazaar examples reference tutorial uppsrc || die
	make_desktop_entry theide TheIDE /usr/share/${PN}/uppsrc/ide/theide-48.png
}